Referencias a almacenamiento anónimo

Listas Anónimas

Una lista de expresiónes entre corchetes como:

[ 'e1', 'e2', 'e3'];

se denomina array anónimo. La expresión devuelve una referencia a un array con esos elementos. Así es posible asignarlo a una variable escalar:

$rb = [ 'e1', 'e2', 'e3'];

Observe el uso de corchetes en vez de paréntesis. Aqui el array no tiene nombre, quien tiene nombre es la referencia. Por supuesto, @$rb denota al array referido.

Hashes Anónimos

Lo mismo puede hacerse con los hashes. en vez de corchetes se usan llaves:

$association = { cat =>"nap", dog=>"gone", mouse=>"ball"};
print "When I say 'cat', you say ...",$association->{cat};

En este caso se dice que tenemos un hash anónimo.

Subrutinas Anónimas

También puede hacerse con las subrutinas. Para tener una subrutina anónima basta con suprimir el nombre de la subrutina:

$subref = sub { my $x = shift; $x*$x; };

Ejercicio 4.4.1  

• ¿Que sucede si en vez de corchetes usamos paréntesis? Si escribimos:

  $rb = ( 'e1', 'e2', 'e3');
  

  ¿Que contiene $rb?

• ¿Que sucede si en vez de llaves usamos paréntesis? Si escribimos:

  $association = ( cat =>"nap", dog=>"gone", mouse=>"ball");
  print "When I say 'cat', you say ...",$association->{cat};
  

  ¿Que contiene $association?

• Explique el significado del siguiente código:

  $association = [ cat =>"nap", dog=>"gone", mouse=>"ball"];
  $a = { @$association }->{mouse};
  

• Explique el significado de las siguientes sentencias y que queda en los diferentes arrays después de ejecutarlas:

    DB<1> opendir D,'./'
    DB<2> @n = readdir D
    DB<3> @nd = map { {N=>$_, D=>-M $_}} @n
    DB<4> @snd = sort { $b->{D} <=> $a->{D} } @nd
    DB<5> @sn = map { $_->{N} } @snd
  

  Recuerde que -M retorna el tiempo desde la última modificación en días.